شمارش کلمات تغییر یافته

Question

استیون همیشه از Track Changes در اسناد خود استفاده می کند. او به راهی برای شمارش فقط کلماتی نیاز دارد که در یک سند تغییر کرده اند – آنهایی که تحت تأثیر تغییرات آهنگ قرار گرفته اند.

پاسخ این است که شما می توانید با استفاده از پنجره بازبینی اطلاعات مورد نظر خود را به دست آورید. تب Review روبان را نمایش دهید، سپس بر روی ابزار Reviewing Pane (در گروه Tracking) کلیک کنید. Word صفحه بازبینی را روی صفحه نمایش می دهد و در بالای صفحه خلاصه ای از اصلاحات انجام شده در سند است. این آمار پنج تغییر زیر را نشان می دهد:

• درج ها
• حذف ها
• حرکت می کند
• تغییرات قالب بندی
• نظرات

ممکن است به نظر برسد که این آمارها مناسب است، اما شما به یاد دارید که گفتم آنها "نوعی" اطلاعات مورد نظر را ارائه می دهند. اگر آنچه شما واقعاً می خواهید تعداد کلمات تغییر یافته باشد، کمی کوتاه است. به عنوان مثال، اگر عبارتی را حذف کنید که از چند کلمه تشکیل شده است، آن ویرایش تنها به عنوان یک حذف در آمار به حساب می آید. به طور مشابه، اگر عبارتی را به سند خود اضافه کنید، آن اضافه به عنوان یک درج واحد محاسبه می شود، حتی اگر درج شامل یک پاراگراف کامل باشد.

اگر می خواهید کلمات واقعی تغییر کنند، متأسفانه شانسی ندارید - Word هیچ راهی برای به دست آوردن اطلاعات مورد نظر ارائه نمی دهد. با این حال، می توانید ماکرو خود را برای تعیین اطلاعات مورد نظر طراحی کنید. در اینجا یک مثال است:

Sub GetTCStats()
    Dim lInsertsWords As Long
    Dim lInsertsChar As Long
    Dim lDeletesWords As Long
    Dim lDeletesChar As Long
    Dim sTemp As String
    Dim oRevision As Revision
    
    lInsertsWords = 0
    lInsertsChar = 0
    lDeletesWords = 0
    lDeletesChar = 0
    For Each oRevision In ActiveDocument.Revisions
        Select Case oRevision.Type
            Case wdRevisionInsert
                lInsertsChar = lInsertsChar + Len(oRevision.Range.Text)
                lInsertsWords = lInsertsWords + oRevision.Range.Words.Count
            Case wdRevisionDelete
                lDeletesChar = lDeletesChar + Len(oRevision.Range.Text)
                lDeletesWords = lDeletesWords + oRevision.Range.Words.Count
        End Select
    Next oRevision

    sTemp = "Insertions" & vbCrLf
    sTemp = sTemp & "    Words: " & lInsertsWords & vbCrLf
    sTemp = sTemp & "    Characters: " & lInsertsChar & vbCrLf
    sTemp = sTemp & "Deletions" & vbCrLf
    sTemp = sTemp & "    Words: " & lDeletesWords & vbCrLf
    sTemp = sTemp & "    Characters: " & lDeletesChar & vbCrLf
    MsgBox sTemp
End Sub

این ماکرو هر تغییر در سند جاری را طی می کند و به طور جداگانه تعداد کلمات و تعداد کاراکترها را برای درج و حذف جمع می کند. سپس آمار در یک جعبه پیام ارائه می شود. توجه داشته باشید که ماکرو برای هر تغییر در سند به مجموعه Words نگاه می کند. باید بدانید که تعداد کلمات، همانطور که در اینجا ارائه شده است، تقریبی است. این به دلیل نحوه شمارش کلمات است. به عنوان مثال، هر علامت نقطه گذاری در یک اضافه به عنوان یک کلمه جداگانه شمرده می شود. این بدان معنی است که عبارتی مانند "همانطور که می توان دید، این یک راه عالی است" به جای 9 به عنوان ده کلمه محاسبه می شود (ویرگول به عنوان یک کلمه جداگانه محسوب می شود). به‌علاوه، اگر عبارتی که اضافه کردید شامل یک فاصله پیشرو باشد - که درج‌ها اغلب انجام می‌دهند - یازده کلمه برای درج به دلیل آن فاصله محاسبه می‌شود.