تنظیم عرض ستون از صفحه کلید

Question

بسیاری از افرادی که با WordPerfect آشنا هستند، بعداً نیاز به یادگیری نحوه استفاده از Word پیدا می کنند. گاهی اوقات انتقال کاملاً روان نیست، تا حد زیادی به این دلیل که وظایف در Word به همان روشی که در WordPerfect انجام می‌شوند انجام نمی‌شوند.

یک مورد بارز تنظیم عرض ستون های جدول با استفاده از صفحه کلید است. WordPerfect، که همیشه یک برنامه "صفحه کلید گرا" بوده است، تنظیمات را آسان می کند: فقط > یا < را فشار دهید تا ستون را پهن یا باریک کنید. از طرف دیگر، Word همیشه بیشتر ماوس گرا بوده و هیچ دستور صفحه کلید معادلی برای این کار ندارد.

راه حل هایی وجود دارد. برای مثال، می‌توانید از صفحه‌کلید برای تایپ Alt+A، R، U استفاده کنید و سپس Tab را چند بار فشار دهید تا به قسمت عرض ستون برسید. البته مشکل این است که تقریباً آسان (یا شهودی) نیست.

اگر از ماوس استفاده نمی‌کنید، می‌توانید کلید Alt را در حین کشیدن حاشیه ستون نگه دارید. خط کش تغییر می‌کند تا عرض دقیق ستون‌های شما را با حرکت دادن حاشیه نشان دهد. بسیار جالب است، اما همچنان برای آن‌ها دردناک است. کسانی که ترجیح می دهند فقط از صفحه کلید استفاده کنند. (همچنین برای کسانی که وضوح ماوس خیلی خوبی ندارند یا نمی توانند ماوس را در فواصل بسیار کوچک حرکت دهند، بسیار مفید نیست.)

شاید بهترین راه حل این باشد که شبیه سازی خود از قابلیت WordPerfect بسازید. ماکرو زیر می تواند این کار را انجام دهد:

Sub StretchColumn()
    Dim iCol As Integer
    Dim sCurrent As Single

    If Selection.Information(wdWithInTable) Then
        If Selection.Columns.Count = 1 Then
            iCol = Selection.Cells(1).ColumnIndex
            sCurrent = Selection.Tables(1).Columns(iCol).Width
            Selection.Tables(1).Columns(iCol).SetWidth _
              ColumnWidth:=sCurrent + 1, RulerStyle:=wdAdjustNone
        Else
            MsgBox ("More than one column selected")
        End If
    Else
        MsgBox ("Insertion point not within a table")
    End If
End Sub

اگر این ماکرو را به یک کلید میانبر اختصاص دهید (همانطور که در شماره های دیگر WordTips توضیح داده شد)، می توانید با هر بار فشار دادن کلید میانبر، عرض ستون جدول فعلی را یک نقطه (1/72 اینچ) افزایش دهید. می توانید یک تغییر ساده در ماکرو ایجاد کنید تا نسخه ای ایجاد کنید که عرض ستون را کاهش دهد، همچنین:

Sub ShrinkColumn()
    Dim iCol As Integer
    Dim sCurrent As Single
    Dim sNext As Single

    If Selection.Information(wdWithInTable) Then
        If Selection.Columns.Count = 1 Then
            iCol = Selection.Cells(1).ColumnIndex
            sCurrent = Selection.Tables(1).Columns(iCol).Width
            sNext = sCurrent - 1
            If sNext < 1 Then sNext = 1
            Selection.Tables(1).Columns(iCol).SetWidth _
              ColumnWidth:=sNext, RulerStyle:=wdAdjustNone
        Else
            MsgBox ("More than one column selected")
        End If
    Else
        MsgBox ("Insertion point not within a table")
    End If
End Sub