ایجاد فهرستی از ماکروها

Question

اندرو یک ورک بوک دارد که تعداد زیادی ماکرو در آن وجود دارد. او می خواهد فهرستی از همه ماکروهای موجود در آن ایجاد کند، بنابراین فکر می کند که آیا راهی برای انجام این کار وجود دارد.

هیچ راه ذاتی در اکسل برای ایجاد لیستی از ماکروها وجود ندارد. با این حال، می توانید یک ماکرو ایجاد کنید که ماکروهای شما را فهرست کند. (نوعی صداهای زائد است، اینطور نیست؟)

به عنوان مثال، ماکرو زیر را در نظر بگیرید، که تمام پروژه های ورک بوک شما را طی می کند تا همه نام های ماکرو را جمع آوری کرده و در یک کاربرگ قرار دهد:

Sub ListMacros()
    Dim VBComp As VBComponent
    Dim wsTarget As Worksheet
    Dim StartLine As Long
    Dim iRow As Integer

    Application.ScreenUpdating = False

    Set wsTarget = Worksheets.Add
    wsTarget.Range("A1") = "Macro"
    wsTarget.Range("A1").Font.Bold = True
    With wsTarget.Range("A1").Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = 0
        .TintAndShade = 0
        .Weight = xlThin
    End With

    iRow = 2

    For Each VBComp In ThisWorkbook.VBProject.VBComponents
        With VBComp.CodeModule
            StartLine = .CountOfDeclarationLines + 1
            Do Until StartLine >= .CountOfLines
                wsTarget.Cells(iRow, 1) = _
                  .ProcOfLine(StartLine, vbext_pk_Proc)
                iRow = iRow + 1
                StartLine = StartLine + _
                  .ProcCountLines(.ProcOfLine(StartLine, _
                  vbext_pk_Proc), vbext_pk_Proc)
            Loop
        End With
    Next VBComp

    wsTarget.Range("A1").EntireColumn.AutoFit
    Application.ScreenUpdating = True
End Sub

برای استفاده از این ماکرو، باید مطمئن شوید که مجموعه مرجع توسعه پذیری Microsoft VBA را دارید. برای انجام این کار؛ این موارد را دنبال کنید:

شکل 1. کادر محاوره ای References.

1. در ویرایشگر VBA، References را از منوی Tools انتخاب کنید. کادر محاوره ای References نمایش داده می شود.
2. در لیست مراجع موجود اسکرول کنید و مطمئن شوید که چک باکس Microsoft Visual Basic for Applications Extensibility انتخاب شده است. (ممکن است یک شماره نسخه در انتهای مرجع وجود داشته باشد، اما باید با کلمات ذکر شده شروع شود.) (شکل 1 را ببینید.)
3. کادر محاوره ای را ببندید.

همچنین باید تغییراتی سریع در تنظیمات مرکز اعتماد خود ایجاد کنید. این مراحل را دنبال کنید:

شکل 2. کادر محاوره ای Trust Center.

1. تب Developer روبان را نمایش دهید.
2. در گروه Code بر روی ابزار Macro Security کلیک کنید. اکسل کادر محاوره ای Trust Center را با گزینه های تنظیمات ماکرو در سمت چپ نمایش می دهد. (شکل 2 را ببینید.)
3. مطمئن شوید که گزینه Trust Access to the VBA Project Object Model انتخاب شده است.
4. روی OK کلیک کنید.

هنگامی که ماکرو را اجرا می کنید، یک کاربرگ جدید به کارنامه شما اضافه می کند و سپس نام همه ماکروها را در همه ماژول های ورک بوک فهرست می کند.