شخصیت ها در حاشیه کنار پاراگراف ها

Question

رالف اسنادی را می نویسد که به کاراکترهای آلفای خاصی در سمت چپ هر پاراگراف نیاز دارند. این حروف باید مانند اعداد خط در حاشیه ظاهر شوند. کاراکترها معمولاً برای کل سند یکسان هستند، به این معنی که آنها از پاراگراف به پاراگراف تغییر نمی کنند.

چند روش وجود دارد که می توانید برای انجام این کار از آنها استفاده کنید. ابتدا می توانید کاراکتر آلفا را در ابتدای هر پاراگراف تایپ کرده و کلید Tab را فشار دهید . سپس پاراگراف را طوری قالب بندی کنید که از یک تورفتگی آویزان استفاده کند که خط اول را کمی در حاشیه سمت چپ قرار می دهد. این را می توان به راحتی با استفاده از سبک هایی که می توان در پاراگراف ها اعمال کرد انجام داد.

اگر پاراگراف های زیادی دارید که می خواهید این کار را با آنها انجام دهید، تایپ کاراکتر آلفا و فشار دادن Tab برای هر پاراگراف می تواند خسته کننده باشد. خوشبختانه، ایجاد یک ماکرو که بتواند از خستگی برای شما مراقبت کند، آسان است.

Sub FmtParagraphs()
    Dim p As Paragraph

    For Each p In ActiveDocument.Content.Paragraphs
        If p.Style = "MyAlpha" Then
            With p.Range
                .InsertBefore "R" & Chr(9)
            End With
        End If
    Next p
End Sub

ماکرو به دنبال هر پاراگراف در سند می گردد که از سبک MyAlpha استفاده می کند. (این فرض را بر این می‌گذارد که MyAlpha" سبک hanging-indent ویژه‌ای است که برای تأثیرگذاری این رویکرد ایجاد کرده‌اید.) وقتی یکی را پیدا کرد، حرف «R» را در جلوی پاراگراف و سپس یک کاراکتر برگه وارد می‌کند. شما به راحتی می‌توانید این ماکرو را تغییر دهید. برای بررسی نام سبک متفاوت یا اضافه کردن یک کاراکتر آلفای متفاوت.

یک رویکرد مشابه، تعریف سبکی است که از یک لیست گلوله ای اصلاح شده استفاده می کند. به جای استفاده از یک گلوله معمولی، می توانید لیستی را برای استفاده از کاراکتر آلفا به عنوان گلوله تعریف کنید. هنگام اعمال سبک روی پاراگراف ها، کاراکتر آلفا به طور خودکار ظاهر می شود و برای جدا کردن آن از بدنه اصلی پاراگراف، نیازی به تایپ آن یا تب ندارید.

هر دو روش ذکر شده تا کنون به سرعت و به راحتی برای اسناد نسبتا ساده کار می کنند. با این حال، اگر اسناد شما شامل لیست‌های شماره‌دار یا گلوله‌ای منظم باشد، آنها کار نمی‌کنند. در این صورت، باید از رویکرد دیگری استفاده کنید - رویکردی که برای قرار دادن کاراکتر آلفا به کادرهای متنی متکی است.

دلیل اینکه این رویکرد ممکن است برای اسناد پیچیده ارجح باشد این است که بر سبک‌ها تکیه نمی‌کند. این بدان معناست که شما می‌توانید لیست‌های شماره‌دار و گلوله‌دار زیادی را در اسناد خود داشته باشید، اما همچنان کاراکترهای آلفا را در سمت چپ هر پاراگراف قرار دهید. علاوه بر این، جعبه‌های متن را می‌توان به گونه‌ای قالب‌بندی کرد که به هر پاراگراف متصل شوند و با پاراگراف حرکت کنند زیرا Word سند را مجدداً صفحه‌بندی می‌کند.

البته، اگر سندی دارید که 300 پاراگراف در آن وجود دارد، افزودن کادرهای متنی به هر پاراگراف می تواند خسته کننده باشد، البته زمانی که شروع به قالب بندی هر جعبه متنی می کنید آزاردهنده نیست. باز هم، ماکروها می توانند به کاهش خستگی کمک کنند. ماکرو زیر را می توان برای کپی خودکار یک جعبه متن انتخاب شده در تمام پاراگراف های دیگر در یک سند استفاده کرد.

Sub TextBoxesInMargin()
    Dim aShape As Shape
    Dim aPara As Paragraph
    Dim j As Long
    Dim shpTop As Single
    Dim shpLeft As Single
    Dim aRange As Range

    If ActiveDocument.Shapes.Count = 0 Then GoTo noTextbox
    If Selection.ShapeRange.Count <> 1 Then GoTo noTextbox

    Set aShape = Selection.ShapeRange(1)
    With aShape
        If .Type <> msoTextBox Then GoTo noTextbox
        If aShape.RelativeVerticalPosition <> wdRelativeVerticalPositionParagraph Then
            MsgBox "The text box must be positioned relative to a paragraph"
            Exit Sub
        End If
        shpTop = .Top
        shpLeft = .Left
        aShape.Select
        Selection.Copy
    End With

    For Each aPara In ActiveDocument.Paragraphs
        Set aRange = aPara.Range
        If Len(aRange.Text) > 1 Then " only non blank paragraphs
            aRange.Select
            Selection.Paste
            Selection.ShapeRange.Top = shpTop
            Selection.ShapeRange.Left = shpLeft
        End If
    Next aPara
    Exit Sub

noTextbox:
    MsgBox "Text box is not selected"
End Sub

برای استفاده از ماکرو، یک جعبه متن کوچک را برای نگه داشتن کاراکتر آلفا قالب بندی کنید. اطمینان حاصل کنید که جعبه متن به پاراگرافی که آن را در کنار آن قرار می‌دهید متصل است و موقعیت آن نسبت به پاراگراف درست است. هنگامی که جعبه متن دقیقاً همان طور که می خواهید به نظر برسد، آن را انتخاب کنید و سپس ماکرو را اجرا کنید. کادر متن در کنار هر پاراگراف دیگر در سند کپی و جایگذاری می شود.