تبدیل پاراگراف ها به نظرات

Question

هنگام توسعه یک سند، استفاده از یک سبک پاراگراف خاص برای یادداشت های سرمقاله غیرعادی نیست. به عنوان مثال، یادداشت ها ممکن است با استفاده از سبکی به نام "یادداشت ها" در پاراگراف ها ذخیره شوند. در برخی مواقع، ممکن است بخواهید تمام پاراگراف هایی را که از سبک Notes استفاده می کنند، بردارید و آنها را به نظرات واقعی در سند تبدیل کنید. می توانید سند را مرور کنید و تبدیل را به صورت دستی انجام دهید، اما این می تواند به سرعت خسته کننده شود. در عوض، از یک ماکرو استفاده کنید که تبدیل را برای شما انجام می دهد:

Sub ConvertNotesToComments()
    Dim CommentText As String
    Dim MyRange As Range
    Dim iPCount As Integer
    Dim J As Integer

    Application.ScreenUpdating = False
    iPCount = ActiveDocument.Paragraphs.Count

    For J = iPCount To 1 Step -1
        If ActiveDocument.Paragraphs(J).Style = _
          ActiveDocument.Styles("Notes") Then
            Set MyRange = ActiveDocument.Paragraphs(J).Range
            CommentText = MyRange.Text

            "Get rid of trailing end-of-paragraph mark
            CommentText = Left(CommentText, Len(CommentText) - 1)

            "Move selection to end of previous paragraph
            MyRange.Collapse (wdCollapseStart)
            MyRange.Move Unit:=wdCharacter, Count:=-1

            "The original paragraph is no longer necessary
            ActiveDocument.Paragraphs(J).Range.Delete

            "Create the comment at the range location
            ActiveDocument.Comments.Add Range:=MyRange, _
              Text:=CommentText
        End If
    Next J
    Application.ScreenUpdating = True
End Sub

ماکرو از طریق سند به عقب برمی‌گردد و به سبک هر پاراگراف نگاه می‌کند. اگر یکی را بیابد که از سبک Notes استفاده می کند، سپس متن پاراگراف را به متغیر CommentText منتقل می کند و سپس از شر پاراگراف خلاص می شود. سپس نظر قبل از جایی که حذف انجام شده است به انتهای پاراگراف اضافه می شود.

قبل از پایان دادن به این نکته، باید مطمئن شوم که فقط کمی توضیح داده ام. از زمان نوشتن این مقاله، مایکروسافت عباراتی را که استفاده می کند تغییر داده است. "نظرات" اکنون بحث های رشته ای هستند و نظرات سنتی اکنون "یادداشت ها" نامیده می شوند. این نه تنها آب را گل آلود کرد (و توضیحات را دشوارتر کرد، بلکه باعث غوغایی در جامعه Word شد.

نکته مطرح کردن این موضوع این است که هرگونه اشاره به نظرات در این نکته به نظرات سنتی اشاره دارد که اکنون ممکن است آنها را به عنوان یادداشت بشناسید. بنابراین، ماکرو بالا پاراگراف ها را به چیزی تبدیل می کند که مایکروسافت اکنون Notes می نامد.