ساخت همه موارد پررنگ

Question

تام به درستی اشاره می کند که در Word می توانید از Find and Replace برای پررنگ کردن همه موارد یک کلمه استفاده کنید. (کلمه را جستجو کنید، آن را با همان کلمه جایگزین کنید که قالب بندی پررنگ روشن است.) او تعجب می کند که چگونه می تواند همان کار را در اکسل انجام دهد.

ایجاد چنین تغییراتی در اکسل در واقع بسیار آسان است و تقریباً به همان روشی که در Word انجام می دهید انجام می شود. این مراحل را دنبال کنید:

شکل 1. تب Replace گسترش یافته از کادر محاوره ای Find and Replace.

شکل 2. تب Font از کادر محاوره ای Replace Format.

1. Ctrl+H را فشار دهید تا تب Replace در کادر محاوره ای Find and Replace نمایش داده شود.
2. روی دکمه Options کلیک کنید تا کادر محاوره ای باز شود. (شکل 1 را ببینید.)
3. در کادر Find What کلمه ای را که می خواهید پررنگ کنید وارد کنید.
4. همان کلمه را در کادر Replace With وارد کنید.
5. روی دکمه Format در سمت راست کادر Replace With کلیک کنید. اکسل کادر محاوره ای Replace Format را نمایش می دهد.
6. روی تب Font کلیک کنید. (شکل 2 را ببینید.)
7. در لیست Font Style، Bold را انتخاب کنید.
8. برای بستن کادر محاوره ای Replace Font روی OK کلیک کنید.
9. برای انجام تعویض روی Replace All کلیک کنید.

در حالی که این کار بسیار آسان به نظر می رسد، باید به خاطر داشته باشید که این مراحل قالب بندی کل سلول ها را تغییر می دهد، نه فقط کلمات داخل یک سلول. بنابراین، اگر کلمه "قهوه ای" را جستجو و جایگزین می کردید، هر سلولی که حاوی کلمه "قهوه ای" باشد پررنگ می شود - کل سلول، نه فقط کلمه.

اگر می خواهید فقط روی کلمات درون سلول تأثیر بگذارید، این مراحل کار نمی کنند. درعوض، باید به یک کلان متوسل شوید تا جسورانه را انجام دهید. اساساً به یک ماکرو نیاز دارید که از طریق یک کاربرگ نگاه کند و تعیین کند چه چیزی را می توان تغییر داد. (شما نمی توانید کلمات یا ارقام جداگانه را در فرمول ها یا مقادیر عددی پررنگ کنید؛ فقط می توانید در قالب بندی سطح کلمه برای ثابت های متن تغییراتی ایجاد کنید.)

هنگامی که ماکرو سلول هایی را پیدا کرد که می تواند پردازش کند، باید در سلول ها کلمه مورد نظر را جستجو کند و سپس آن متن را پررنگ کند. ماکرو زیر همین استراتژی را اجرا می کند:

Sub FindAndBold()
    Dim sFind As String
    Dim rCell As Range
    Dim rng As Range
    Dim lCount As Long
    Dim iLen As Integer
    Dim iFind As Integer
    Dim iStart As Integer

    On Error Resume Next
    Set rng = ActiveSheet.UsedRange. _
      SpecialCells(xlCellTypeConstants, xlTextValues)
    On Error GoTo ErrHandler
    If rng Is Nothing Then
        MsgBox "There are no cells with text"
        GoTo ExitHandler
    End If

    sFind = InputBox( _
      Prompt:="What do you want to BOLD?", _
      Title:="Text to Bold")
    If sFind = "" Then
        MsgBox "No text was listed"
        GoTo ExitHandler
    End If

    iLen = Len(sFind)
    lCount = 0

    For Each rCell In rng
        With rCell
            iFind = InStr(.Value, sFind)
            Do While iFind > 0
                .Characters(iFind, iLen).Font.Bold = True
                lCount = lCount + 1
                iStart = iFind + iLen
                iFind = InStr(iStart, .Value, sFind)
            Loop
        End With
    Next

    If lCount = 0 Then
        MsgBox "There were no occurrences of" & _
          vbCrLf & " " & sFind & " " & _
          vbCrLf & "to bold."
    ElseIf lCount = 1 Then
        MsgBox "One occurrence of" & _
          vbCrLf & " " & sFind & " " & _
          vbCrLf & "was made bold."
    Else
        MsgBox lCount & " occurrences of" & _
          vbCrLf & " " & sFind & " " & _
          vbCrLf & "were made bold."
    End If

ExitHandler:
    Set rCell = Nothing
    Set rng = Nothing
    Exit Sub

ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler
End Sub

ماکرو ابتدا محدوده جستجو را روی آن سلول هایی که حاوی ثابت های متنی هستند تنظیم می کند. سپس از کاربر می خواهد کلمه ای را که باید تغییر کند. پس از وارد شدن، ماکرو شروع به جستجو در تمام سلول های محدوده می کند. هر سلول بررسی می شود تا ببینیم آیا حاوی کلمه مورد نظر است یا خیر. اگر چنین است، ویژگی .Bold برای آن کاراکترها تنظیم می شود و ماکرو به جستجو ادامه می دهد.

ماکرو همچنین تعداد تغییرات ایجاد شده را پیگیری می کند و کل تغییرات را در پایان کار خود نمایش می دهد.