کپی کردن سرصفحه ها یا پاورقی ها در ورک بوک

Question

راس یک ورک بوک موجود دارد که شامل 36 کاربرگ است. او در اولین کاربرگ فوترها را آنطور که می خواهد تنظیم کرد. راس به این فکر می کند که آیا راه آسانی برای کپی کردن پاورقی ها از اولین کاربرگ به همه کاربرگ های دیگر در ورک بوک وجود دارد.

انجام این کار در اکسل بسیار آسان است. تنها کاری که باید انجام دهید این است که این مراحل را دنبال کنید:

شکل 1. مجموعه انتخابی از برگه های کاربرگ.

1. اولین کاربرگ خود را انتخاب کنید، صفحه ای که سرصفحه ها و پاورقی ها را همانطور که می خواهید دارد.
2. اکنون، در قسمت برگه کاربرگ در پایین پنجره اکسل، کلید Shift را نگه دارید، همانطور که روی برگه آخرین کاربرگی که می خواهید روی آن کلیک کنید، کلیک کنید. اکنون یک مجموعه انتخابی از کاربرگ ها ایجاد کرده اید، و اولین کاربرگ شما همچنان باید کاربرگ فعال باشد. (شما می توانید این را بگویید زیرا زیر خط سبز روی خود برگه وجود دارد.) (شکل 1 را ببینید.)
3. تب Page Layout روبان را نمایش دهید.
4. روی نماد کوچک در پایین سمت راست گروه Page Setup کلیک کنید. اکسل کادر محاوره ای Page Setup را نمایش می دهد.
5. مطمئن شوید که تب Header/Footer نمایش داده شده است. سرصفحه ها و پاورقی هایی که در کادر محاوره ای نشان داده شده اند باید منعکس کننده صفحه کاری فعال باشند، که صفحه کاری است که برای اولین بار در مرحله 1 انتخاب کردید.
6. روی OK کلیک کنید. همه کاربرگ هایی که در مرحله 2 انتخاب کردید همچنان انتخاب شده اند.
7. روی هر برگه کاربرگ دیگری غیر از برگه فعال (آنی که زیرخط سبز دارد) کلیک کنید. با این کار مجموعه انتخابی شما لغو می شود.

خودشه؛ سرصفحه ها و پاورقی ها از کاربرگ فعال در تمام کاربرگ هایی که انتخاب کرده اید کپی می شوند. تمامی سرصفحه ها و پاورقی های قبلی در کاربرگ های انتخاب شده در این فرآیند بازنویسی می شوند.

کلید موفقیت در این مراحل این است که مطمئن شوید کاربرگ فعال، برگه ای است که سرصفحه و پاورقی مورد نظر شما را دارد. این همان کاربرگی است که باید در مرحله 1 انتخاب می کردید و برگه ای است که زیر خط سبز روی برگه کاربرگ دارد، همانطور که در مرحله 2 شرح داده شد. کادر محاوره ای Layout در مرحله 5. (اگر سرصفحه و پاورقی مناسب را در مرحله 5 مشاهده نکردید، باید بلافاصله Esc را فشار دهید یا روی Cancel در کادر محاوره ای کلیک کنید تا سرصفحه ها و پاورقی ها را کپی نکنید.)

اگر می خواهید فقط پاورقی ها را کپی کنید (و سرصفحه ها را همانطور که هستند رها کنید، که به نظر می رسد راس مایل است)، پس باید به استفاده از ماکرو متوسل شوید. در اینجا یک ماکرو ساده وجود دارد که هر متنی را فقط در فوترها مدیریت می کند:

Sub CopyFooters()
    Dim wSource As Worksheet
    Dim sSourceName As String
    Dim bFP As Boolean
    Dim bEP As Boolean
    Dim wSFP As Object
    Dim wSEP As Object
    Dim w As Worksheet

    Set wSource = ActiveWorkbook.Worksheets("Sheet1")
    sSourceName = wSource.Name
    Set wSFP = wSource.PageSetup.FirstPage
    Set wSEP = wSource.PageSetup.EvenPage

    With wSource.PageSetup
        bFP = .DifferentFirstPageHeaderFooter
        bEP = .OddAndEvenPagesHeaderFooter
    End With

    For Each w In ActiveWorkbook.Worksheets
        With w.PageSetup
            .DifferentFirstPageHeaderFooter = bFP
            .OddAndEvenPagesHeaderFooter = bEP

            .LeftFooter = wSource.PageSetup.LeftFooter
            .CenterFooter = wSource.PageSetup.CenterFooter
            .RightFooter = wSource.PageSetup.RightFooter

            If bFP Then
                With .FirstPage
                    .LeftFooter.Text = wSFP.LeftFooter.Text
                    .CenterFooter.Text = wSFP.CenterFooter.Text
                    .RightFooter.Text = wSFP.RightFooter.Text
                End With
            End If

            If bEP Then
                With .EvenPage
                    .LeftFooter.Text = wSEP.LeftFooter.Text
                    .CenterFooter.Text = wSEP.CenterFooter.Text
                    .RightFooter.Text = wSEP.RightFooter.Text
                End With
            End If
        End With
    Next w
End Sub

اگر کد را به دقت بررسی کنید، متوجه خواهید شد که تفاوتی در نحوه ارجاع محتوای پاورقی بر اساس اینکه پاورقی یک فوتر معمولی، یک فوتر صفحه اول یا یک پاورقی صفحه زوج است، وجود دارد. به طور خاص، پاورقی های غیر عادی از ویژگی متن استفاده می کنند، در حالی که پاورقی های معمولی از ویژگی متن استفاده می کنند. این به این دلیل است که (ظاهراً) VBA زمانی که از ویژگی های .LeftFooter، .CenterFooter و RightFooter شی .PageSetup استفاده می کنید، به طور پیش فرض از ویژگی .Text استفاده می کند. با این حال، اگر از همان ویژگی های پاورقی با اشیاء .FirstPage یا .EvenPage استفاده کنید، ویژگی .Text فرض نمی شود - باید به طور خاص بیان شود. بدون اینکه همانطور که در اینجا نشان داده شده است مشخص شود، ماکرو از کار می افتد.

اگر می خواهید از ماکرو استفاده کنید، تنها کاری که باید انجام دهید این است که مطمئن شوید مرجع «Sheet1» به نام صفحه ای که می خواهید پاورقی ها را از آن کپی کنید، تغییر کرده است.