حاشیه پاکت پیش فرض

Question

Word به شما اجازه نمی دهد موقعیت های پیش فرض را که در آن آدرس برگشتی و آدرس اصلی روی پاکت چاپ می شود را به راحتی تغییر دهید. راه های مختلفی برای حل این مشکل وجود دارد که هر کدام از آنها ماهیت انعطاف پذیر Word را برای انجام یک کار مثال می زند.

به نظر می رسد که تنظیمات پاکت نامه به عنوان بخشی از سند شما ذخیره می شود و بنابراین می توان آن را در یک الگو ذخیره کرد. اگر فقط یک اندازه پاکت را چاپ می کنید، ساده ترین راه برای تغییر موقعیت چاپ پیش فرض پاکت نامه این است که مراحل زیر را دنبال کنید:

شکل 1. برگه پاکت در کادر محاوره ای پاکت ها و برچسب ها.

شکل 2. کادر محاوره ای گزینه های پاکت.

1. قالب Normal را بارگیری کنید. (این الگوی پیش‌فرض است که هر زمان که یک سند خالی ایجاد می‌کنید توسط Word استفاده می‌شود.)
2. تب Mailings روبان را نمایش دهید.
3. روی ابزار Envelopes در گروه Create کلیک کنید. Word کادر محاوره‌ای پاکت‌ها و برچسب‌ها را با انتخاب تب پاکت‌ها نمایش می‌دهد. (شکل 1 را ببینید.)
4. بر روی دکمه Options کلیک کنید. Word کادر محاوره ای گزینه های پاکت را نمایش می دهد.
5. مطمئن شوید که تب گزینه های پاکت انتخاب شده است. (شکل 2 را ببینید.)
6. در قسمت های مربوطه، موقعیت آدرس ها را به دلخواه تغییر دهید.
7. روی OK کلیک کنید تا کادر گفتگوی Envelope Options بسته شود.
8. بر روی افزودن به سند کلیک کنید. این یک پاکت را در قالب شما قرار می دهد (که باز دارید، یادتان هست؟).
9. از منوی Edit گزینه Select All را انتخاب کنید. با این کار تمام اطلاعات پاکت که به تازگی توسط Word به سند شما اضافه شده است را انتخاب می کند.
10. کلید Del را فشار دهید . پاکت نامه از سند شما حذف می شود.
11. با کلیک بر روی ابزار Save یا با انتخاب Save از منوی File، الگو را ذخیره کنید.
12. قالب را ببندید.

اکنون، دفعه بعد که از یک سند بر اساس سبک عادی استفاده می کنید، تنظیمات پاکت نامه مواردی را که در این مراحل ایجاد کرده اید منعکس می کند.

همچنین می توانید از راه حلی استفاده کنید که از یک ماکرو برای ایجاد پاکت نامه های خود استفاده می کند. به عنوان مثال، می توانید با یک سند جدید و خالی شروع کنید و پاکت نامه ای درست کنید که می خواهید باشد. این پاکت را به سند خالی اضافه کنید و سپس با استفاده از یک نام توصیفی (مانند Envelope.dot) آن را به عنوان یک الگو ذخیره کنید. سپس، ماکرو زیر را ایجاد کرده و آن را به نوار ابزار دسترسی سریع اختصاص دهید:

Sub DoEnv()
    Documents.Add Template:="Envelope", NewTemplate:=False
    Selection.EndKey Unit:=wdStory
    Selection.MoveLeft Unit:=wdCharacter, Count:=2
    Selection.PasteSpecial DataType:=wdPasteText
    Application.PrintOut Range:=wdPrintCurrentPage
    ActiveWindow.Close (False)
End Sub

برای چاپ یک پاکت، آدرس را در یک حرف برجسته کنید و سپس روی دکمه نوار ابزار دسترسی سریع که این ماکرو با آن مرتبط است کلیک کنید. ماکرو آدرس را در کلیپ بورد کپی می کند، آن را در جای مناسب در یک سند جدید بر اساس الگوی پاکت می چسباند، پاکت نامه را چاپ می کند و سپس سند پاکت را بدون ذخیره می بندد.

یک رویکرد متفاوت این است که از یک ماکرو برای تنظیم تنظیمات پاکت استاندارد (یعنی مواردی که می خواهید بیشتر استفاده کنید) استفاده کنید. ماکرو زیر دقیقاً این کار را انجام می دهد:

Sub ToolsEnvelopesAndLabels()
    Dim EnvThere As Integer
    Dim recipient As String
    EnvThere = False
    recipient = Selection.Text
    On Error Resume Next
    If IsError(ActiveDocument.Envelope.Address) Then
        ActiveDocument.Envelope.Insert
        EnvThere = True
    End If
    With ActiveDocument.Envelope
        .DefaultFaceUp = True
        .DefaultOrientation = wdCenterClockwise
        .DefaultHeight = CentimetersToPoints(11)
        .DefaultWidth = CentimetersToPoints(22)
        .AddressFromLeft = CentimetersToPoints(5)
        .AddressFromTop = CentimetersToPoints(5)
        .ReturnAddressFromLeft = CentimetersToPoints(2)
        .ReturnAddressFromTop = CentimetersToPoints(2)
    End With
    If EnvThere Then
        ActiveDocument.Sections(1).Range.Delete
    Else
        ActiveDocument.Envelope.UpdateDocument
    End If
    With Application.Dialogs(wdDialogToolsCreateEnvelope)
        .ExtractAddress = True
        If .AddrText = "" Then
            .AddrText = recipient
        End If
        .Show
    End With
End Sub

برای استفاده از این ماکرو ابتدا آدرسی را که می خواهید روی پاکت استفاده شود انتخاب کنید. اگر آدرس دیگری از قبل تعریف نشده باشد، ماکرو انتخاب فعلی را می گیرد و از آن به عنوان آدرس پاکت استفاده می کند. سپس تابع IsError تعیین می کند که آیا یک پاکت قبلاً وجود دارد یا خیر. اگر یکی نباشد، یک مورد جدید درج می‌شود و EnvThere تنظیم می‌شود که به ما بگوید پس از تغییر ویژگی‌های پیش‌فرض آن را حذف کنیم. هنگامی که یک پاکت در سند وجود داشت، سپس ویژگی‌های پیش‌فرض پاکت را تغییر می‌دهیم. این کار در انجام می‌شود. بخش With ActiveDocument.Envelope. می توانید این ویژگی ها را در صورت نیاز سفارشی کنید یا به سادگی آنها را حذف کنید. (این مثال از تابع CentimetersToPoints برای تنظیم مقادیر استفاده می کند؛ در صورت تمایل می توانید از توابع دیگری مانند InchesToPoints استفاده کنید.