تقسیم صفحه به صورت ناهموار بین دو ورک بوک

Question

اغلب وقتی دیو دو ورک بوک باز دارد، از Arrange | استفاده می کند افقی برای مشاهده آنها به طور همزمان. این فضا را به طور مساوی بین دو ورک بوک تقسیم می کند. با این حال، اغلب اتفاق می افتد که دیو مایل است فقط چند ردیف از داده ها را در یک ورک بوک و بسیاری از ردیف ها را در دیگری ببیند. او نمی پرسد آیا راه مناسبی برای اندازه گیری دستی ورک بوک کوچک تر وجود دارد و اکسل فضای باقی مانده روی صفحه را با ورک بوک دوم پر می کند.

روش دستی انجام این کار روشی است که دیو (و اکثر کاربران دیگر اکسل) قبلاً با آن آشنا هستند: شما پنجره ها را به صورت افقی مرتب می کنید، اندازه پنجره بالا را تغییر می دهید و سپس اندازه پنجره پایین را تغییر می دهید. به این ترتیب می توانید پنجره ها را به همان شکلی که می خواهید برای انجام کارتان بسازید.

اگر می خواهید روش خودکارتری برای تغییر اندازه ویندوز داشته باشید، می توانید از یک ماکرو برای انجام کار استفاده کنید. ماکرو زیر به شما متکی است تا پنجره اول را به صورتی که می خواهید اندازه بگیرید و سپس به طور خودکار اندازه پنجره دوم را تغییر می دهد تا فضای باقی مانده زیر پنجره بالا را اشغال کند.

Sub UnevenSplit1()
    Dim Ht0 As Single
    Dim Ht1 As Single
    Dim Ht2 As Single
    Dim Top2 As Single

    If Windows.Count = 2 Then
        With Windows(1)
            Ht1 = .Height
            .WindowState = xlMaximized
            Ht0 = .Height
        End With
        Top2 = Ht1 + 3
        Windows.Arrange ArrangeStyle:=xlHorizontal
        With Windows(1)
            .Top = 1
            .Height = Ht1
        End With
        With Windows(2)
            .Top = Top2
            .Height = Ht0 - Ht1 - 22
        End With
        Windows(1).Activate
    End If
End Sub

ماکرو فقط در صورتی اندازه پنجره های ورک بوک شما را تغییر می دهد که فقط دو ورک بوک باز داشته باشید. اگر بیشتر یا کمتر از این داشته باشید، به نظر می رسد که هیچ اتفاقی نمی افتد.

همچنین می توانید با تغییر اندازه ماکرو پنجره بالا، اتوماسیون را یک مرحله دیگر بردارید. مثال زیر به این نتیجه می رسد که پنجره بالایی شما 25٪ از صفحه و پنجره پایینی 75٪ را اشغال می کند.

Sub UnevenSplit()
    Dim sQtr As Single

    If Windows.Count = 2 Then
        Windows.Arrange ArrangeStyle:=xlHorizontal
        sQtr = Windows(1).Height / 2
        Windows(1).Top = 1
        Windows(1).Height = sQtr
        Windows(2).Top = sQtr + 3
        Windows(2).Height = sQtr * 3
        Windows(1).Activate
    End If
End Sub

همچنین باید توجه داشته باشید که ارزش این ماکرو تا حد زیادی به آنچه در ویندوز خود مشاهده می کنید بستگی دارد. اگر روبان ها را در عمق عمودی کامل خود دارید، فضای زیادی از صفحه را می گیرد. در واقع، ممکن است آنقدر طول بکشد که حتی اگر پنجره بالایی 25 درصد از ارتفاع صفحه را اشغال کند، ممکن است هیچ ردیفی از کاربرگ شما را نشان ندهد زیرا فضا توسط نوار و سایر عناصر رابط اشغال شده است.

دو راه حل ممکن وجود دارد. اولین مورد، به حداقل رساندن عناصر صفحه نمایش، مانند روبان است. (روی هر تب روبان دوبار کلیک کنید تا نوار روبان به حداقل برسد.) البته راه حل دیگر این است که ماکرو از محاسبات مختلف برای تعیین اندازه نهایی پنجره ها استفاده کند.