الگوها و تنظیم صفحه

Question

مسائل دیگر WordTips به نحوه استفاده از الگوها پرداخته است. قالب‌ها چیزی نیستند جز مجموعه‌های خاصی از سبک‌ها، ماکروها، نوارهای ابزار، و دیگر «خوبی‌ها» که محیط Word شما را تعریف می‌کنند. می‌توانید ظاهر یک سند را به سادگی با تغییر الگوی پیوست شده به سند و سپس اعمال سبک‌ها، در صورت لزوم، تغییر دهید. با استفاده از کادر محاوره ای Templates and Add-ins، الگوی پیوست شده به یک سند را تغییر می دهید. شما این کادر محاوره ای را با نمایش تب Developer از روبان و سپس کلیک کردن روی Document Template در گروه Templates نمایش می دهید. (شکل 1 را ببینید.)

شکل 1. کادر محاوره ای Templates and Add-ins.

وقتی الگوهای یک سند را تغییر می‌دهید، همه چیز از الگوی جدید روی سند اعمال نمی‌شود. به عنوان مثال، تنظیمات صفحه برای الگو بر روی یک سند اعمال نمی شود. این می تواند خسته کننده باشد، تا زمانی که متوجه شوید که استفاده از آن می تواند مشکلات زیادی ایجاد کند. چرا؟ از آنجا که اطلاعات تنظیم صفحه، در ورد، یک ویژگی بخش است. این بدان معنی است که می توانید تنظیمات صفحه را برای هر بخش تعریف شده در سند خود تغییر دهید. هنگامی که یک الگوی جدید را به یک سند پیوست می‌کنید، Word چگونه باید بداند که تنظیمات صفحه کدام بخش‌ها باید رونویسی شوند؟ اگر تنظیمات صفحه را از الگو در تمام بخش‌های سند اعمال کند، ممکن است مقدار زیادی از آن را از دست بدهید. کار کردن

با این حال، هنگامی که برای اولین بار یک سند را بر اساس یک الگو ایجاد می کنید، چنین مشکلی وجود ندارد. در این مورد، سند جدید به سادگی بازتابی از کل سند الگو است.

با این درک، اگر هنوز می‌خواهید اطلاعات تنظیمات صفحه را از یک الگو در سند فعلی اعمال کنید، می‌توانید به راحتی با استفاده از یک ماکرو این کار را انجام دهید. ماکرو زیر می تواند به عنوان راهنمای شما باشد:

Sub ApplyTemplatePageSetup()
    Dim Tmpl As String
    Dim CurDoc As Document

    Tmpl = ActiveDocument.AttachedTemplate
    Set CurDoc = ActiveDocument
    Documents.Add Template:=Tmpl

    With CurDoc.PageSetup
        .LineNumbering.Active = _
          ActiveDocument.PageSetup.LineNumbering.Active
        .Orientation = ActiveDocument.PageSetup.Orientation
        .TopMargin = ActiveDocument.PageSetup.TopMargin
        .BottomMargin = ActiveDocument.PageSetup.BottomMargin
        .LeftMargin = ActiveDocument.PageSetup.LeftMargin
        .RightMargin = ActiveDocument.PageSetup.RightMargin
        .Gutter = ActiveDocument.PageSetup.Gutter
        .HeaderDistance = ActiveDocument.PageSetup.HeaderDistance
        .FooterDistance = ActiveDocument.PageSetup.FooterDistance
        .PageWidth = ActiveDocument.PageSetup.PageWidth
        .PageHeight = ActiveDocument.PageSetup.PageHeight
        .FirstPageTray = ActiveDocument.PageSetup.FirstPageTray
        .OtherPagesTray = ActiveDocument.PageSetup.OtherPagesTray
        .OddAndEvenPagesHeaderFooter = _
          ActiveDocument.PageSetup.OddAndEvenPagesHeaderFooter
        .DifferentFirstPageHeaderFooter = _
          ActiveDocument.PageSetup.DifferentFirstPageHeaderFooter
        .SuppressEndnotes = ActiveDocument.PageSetup.SuppressEndnotes
        .MirrorMargins = ActiveDocument.PageSetup.MirrorMargins
    End With
    ActiveDocument.Close SaveChanges:=wdDoNotSaveChanges

    Set CurDoc = Nothing
End Sub

این ماکرو الگوی مورد استفاده را تعیین می‌کند، یک سند جدید بر اساس آن الگو ایجاد می‌کند و سپس اطلاعات تنظیم صفحه را از سند جدید به سند اصلی کپی می‌کند. پس از تکمیل، سند جدید ایجاد شده توسط ماکرو حذف می شود. می‌توانید هر قسمتی از ماکرو را که فکر نمی‌کنید قابل اجرا هستند حذف کنید. برای مثال، اگر فقط می‌خواهید حاشیه‌ها را مطابق با الگوی خود تغییر دهید، تنها چیزی که باید در این ماکرو نگه دارید، چهار خطی است که حاشیه‌ها را تعیین می‌کنند.

بدیهی است که این ماکرو هرگونه اطلاعات تنظیم صفحه در سند شما را لغو می کند. (این ایده اصلی است، درست است؟)